WRDS 实战 - 美国上市公司会计保守主义计算方法

美国上市公司会计保守主义计算方法

0 准备工作

预处理 CCM 数据库

见我的上期文章：WRDS 实战 - CCM 的下载与预处理

1 会计保守主义计算方法

参考文献：

Khan, M., & Watts, R. L. (2009). Estimation and empirical properties of a firm-year measure of accounting conservatism. Journal of Accounting and Economics, 48(2), 132–150.

构建模型：

$$
\begin{aligned}
X_i &= \delta_1 + \delta_2 Size_i + \delta_3 M / B + \delta_4 Lev_i \\
&+ D_i (\gamma_1 + \gamma_2 Size_i + \gamma_3 M / B + \gamma_4 Lev_i) \\
&+ R_i \left( \mu_1 + \mu_2 Size_i + \mu_3 M / B + \mu_4 Lev_i \right) \\
&+ D_i R_i \left( \lambda_1 + \lambda_2 Size_i + \lambda_3 M / B + \lambda_4 Lev_i \right) \\
&+ \varepsilon_i
\end{aligned}
$$

其中，
$X$：Earnings，定义为特殊项目前收入除以总市值
$R$：Returns，定义为前一个会计年度结束后第四个月开始算的、累计 12 个月的收益率（用月收益率加一相乘）

这里为了方便，直接采用收盘价 prcc_f 来计算了，后面有机会出一期 CRSP 的月收益率与会计年度的合并推送，然后把这个指标的计算补上

$D$：虚拟变量，在 $R < 0$ 时取值为 1
$Size$：市值自然对数
$M/B$：市值账面比。总市值除以账面价值
$Lev$：杠杆率，定义为长短期负债总和除以总市值

根据作者建议，还要剔除：

1. 收盘价低于 $1 的观测
2. 所有变量上下 1% 的样本

2 Stata 实操

use "CCM.dta", clear
xtset gvkey fyear

gen X = ib / (prcc_f * csho)
gen R = D.prcc_f / L.prcc_f
gen D = (R < 0) if !mi(R) // wrong but easy
gen DR = D * R

gen SIZE = ln(prcc_f * csho)
gen MB = prcc_f * csho / ceq
gen LEV = (dltt + dlc) / (prcc_f * csho)

foreach v of varlist R D DR{
    gen `v'SIZE = `v' * SIZE
    gen `v'MB = `v' * MB
    gen `v'LEV = `v' * LEV
}

drop if prcc_f < 1
winsor2 X R SIZE MB LEV, cut(1, 99) trim replace
asreg X R-DRLEV, by(fyear)

gen GSCORE = _b_R + _b_RSIZE * SIZE + _b_RMB * MB + _b_RLEV * LEV
gen CSCORE = _b_DR + _b_DRSIZE * SIZE + _b_DRMB * MB + _b_DRLEV * LEV

keep gvkey fyear CSCORE GSCORE
save "Conservatism.dta", replace

结果展示：

注：
CSCORE 越大代表越保守，GSCORE 相反